CFLib.org – Common Function Library Project

formatListAsSeries(theList)

Last updated January 14, 2010

author

Mosh Teitelbaum

Version: 2 | Requires: CF5 | Library: StrLib

Description:
Function that formats a numeric list so that successive numbers are shown as a series. List must be numeric. For this function to be useful, list elements should be sorted in ascending order. Updated 1/14/10 by Todd Sharp (todd@cfsilence.com) to sort the list before grouping.

Return Values:
Returns a string.

Example:

<cfoutput>
#formatListAsSeries("2,1,6,4,7,8,10")#
<!--- outputs: 1-2, 4, 6-8, 10 --->
</cfoutput>

Parameters:

Name Description Required
theList The list to parse. Yes

Full UDF Source:

/**
 * Function that formats a numeric list so that successive numbers are shown as a series.
 * 
 * @param theList 	 The list to parse. (Required)
 * @return Returns a string. 
 * @author Mosh Teitelbaum (mosh.teitelbaum@evoch.com) 
 * @version 2, January 14, 2010 
 */
function formatListAsSeries(theList) {
    var lastEle = "";
    var isSet = false;
    var fList = "";
    var currEle = "";
    var idx = 0;
	
	theList = listSort(theList, "numeric", "asc");
	
	for ( idx = 1; idx LTE ListLen(theList); idx = idx + 1 ) {
		currEle = ListGetAt(theList, idx);
		
		if ( Len(lastEle) EQ 0 ) {
			fList = fList & currEle;
			lastEle = currEle;
			isSet = false;
		} else if ( lastEle EQ currEle ) {
			//do nothing
		} else if ( lastEle + 1 NEQ currEle ) {
			if ( isSet ) {
				fList = fList & lastEle;
			}
			fList = fList & ", " & currEle;
			lastEle = currEle;
			isSet = false;
		} else {
		if ( NOT isSet ) {
			fList = fList & "-";
		}
		lastEle = currEle;
		isSet = true;
		}
	}

	if ( isSet ) {
		fList = fList & lastEle;
	}

	return fList;
}
blog comments powered by Disqus

Search CFLib.org


Latest Additions

Kevin Cotton added
date2ExcelDate
May 5, 2016

Raymond Camden added
CapFirst
April 25, 2016

Chris Wigginton added
loremIpsum
January 18, 2016

Gary Stanton added
calculateArrival...
November 19, 2015

Sebastiaan Naafs - van Dijk added
getDaysInQuarter
November 13, 2015

Created by Raymond Camden / Design by Justin Johnson