CFLib.org – listToQuery

listToQuery(list [, delimiters] [, column_name])

Last updated September 9, 2009

Download UDF

author

Russ Spivey
Send Email

Version: 0 | Requires: ColdFusion MX | Library: DataManipulationLib

Rated 14 time(s). Average Rating: 4.6

Description:
Converts a list to a single-column query.

Return Values:
Returns a query.

Example:

Parameters:

Name	Description	Required
list	List of items.	Yes
delimiters	List delimiters. Defaults to a comma.	No
column_name	Name to use for column. Defaults to column.	No

Full UDF Source:

	
	<!---
 Converts a list to a single-column query.
 
 @param list      List of items. (Required)
 @param delimiters      List delimiters. Defaults to a comma. (Optional)
 @param column_name      Name to use for column. Defaults to column. (Optional)
 @return Returns a query. 
 @author Russ Spivey (russellspivey@gmail.com) 
 @version 0, September 9, 2009 
--->
<cffunction name="listToQuery" access="public" returntype="query" output="false" 
    hint="Converts a list to a single-column query.">
    <cfargument name="list" type="string" required="yes" hint="List to convert.">
    <cfargument name="delimiters" type="string" required="no" default="," hint="Things that separate list elements.">
    <cfargument name="column_name" type="string" required="no" default="column" hint="Name to give query column.">
    
    <cfset var query = queryNew(arguments.column_name)>
    <cfset var index = ''>
    
    <cfloop list="#arguments.list#" index="index" delimiters="#arguments.delimiters#">
        <cfset queryAddRow(query)>
        <cfset querySetCell(query,arguments.column_name,index)>
    </cfloop>
    
    <cfreturn query>
</cffunction>