CFLib.org – Common Function Library Project

Description:
Returns the standard deviation calculated using the divisor n method. This method is used when you have all the values for an entire population.

Return Values:
Returns a simple value.

Example:

<CFSET Values="1,2,3,4,5,6,7,8,9,10"> 

  <CFOUTPUT>
  Given <CFIF IsArray(Values)>{#ArrayToList(Values)#}<CFELSE>{#Values#}</CFIF><BR>
  The standard deviation for the population is #StdDevPop(values)#
  </CFOUTPUT>

Parameters:

Full UDF Source:

/**
 * Returns the standard deviation calculated using the divisor n method.
 * 
 * @param values      Comma delimited list or one dimensional array of numeric values. 
 * @return Returns a simple value. 
 * @author Rob Brooks-Bilson (rbils@amkor.com) 
 * @version 1.1, September 7, 2001 
 */
function StdDevPop(values)
{
  Var MyArray = 0;
  Var NumValues = 0;
  Var xBar = 0;
  Var SumxBar = 0;  
  Var i=0;
  if (IsArray(values)){
     MyArray = values;
    }
  else {
     MyArray = ListToArray(values);
    }
  NumValues = ArrayLen(MyArray);
  xBar = ArrayAvg(MyArray);
  for (i=1; i LTE NumValues; i=i+1) {
    SumxBar = SumxBar + ((MyArray[i] - xBar)*(MyArray[i] - xBar));
    }
  Return Sqr(SumxBar/NumValues);
}