CFLib.org – Common Function Library Project

Description:
WSDL is heavy and slow. JSON is much faster but cfinvoke does not supporting invoking cfc method that way.

Return Values:
Any data returned by remote method call.

Example:

ans = invokeRemoteMethodByJSON("http://domain.com/remote.cfc", "sum", {arr=[1,2,3]});

Parameters:

Full UDF Source:

/**
 * Invoke a remote method using cfhttp and JSON proxy
 * v1.0 by Henry Ho
 * 
 * @param url      The URL of the remote component (Required)
 * @param method      The name of the remote method to call (Required)
 * @param args      Any arguments to pass to the method (Optional)
 * @return Any data returned by remote method call. 
 * @author Henry Ho (henryho167@gmail.com) 
 * @version 1.0, March 10, 2013 
 */
function invokeRemoteMethodByJSON(required string url, required string method, struct args){
    var httpService = new http(url=url, method="post");

    httpService.addParam(type="formfield", name="method", value=method);
    httpService.addParam(type="formfield", name="returnformat", value="json");
    httpService.addParam(type="formfield", name="argumentCollection", value=serializeJSON(args));
    
    var result = httpService.send().GetPrefix();
    
    if (len(result.fileContent)) {
        if (!isJson(result.fileContent)){
            throw(message="Non-json string returned", detail=result.fileContent);
        }
            
        return deserializeJSON(result.fileContent);
    }
}